Powerd911 – Numéro #1 au Canada

Comment déplacer le texte de la propriété Description vers la propriété Commentaire automatiquement?

La meilleure façon d’automatiser le déplacement d’un texte de la propriété Description vers la propriété Commentaire est de réaliser un script VB.

Les deux lignes clés du code VB ci-dessous sont :

cls.Comment = Rtf2Ascii (cls.Description)
cls.Description = «  »

La première ligne permet de convertir le texte de la propriété Description du format Rich Text Format (RTF) vers l’ascii via la méthode Rtf2Ascii (), puis affecte le texte à la propriété Commentaire. La deuxième ligne supprime le texte de la propriété Description.

 '******************************************************************************
'* Nom du fichier : DEPLACER_DESC_TO_COM.vbs
'* Définition : Survol l’ensemble des objets afin de déplacer le texte de la propriété description
'*              vers la propriété Commentaire.
'* Modèle: Modèle de données physique (PDM)
'* Objets: Tous
'* Auteur: Benoît Le Nabec
'* URL : http://www.Powerd911.guru
'* Créé: 2015-01-01
'* Version: 1.0
'*****************************************************************************

Option Explicit

Dim cls

ValidationMode = True

InteractiveMode = im_Batch

' On se positionne sur le modèle courant

Dim mdl ' Variable qui référence le modèle courant
Set mdl = ActiveModel

If (mdl Is Nothing) Then
MsgBox "Il n’y a pas présentement de modèle actif"
Else
ListeObjets(mdl)
End If



'Procédure Sub ListeObjets pour survoler le contenu des packages ainsi que les packages enfants

Private Sub ListeObjets(fldr)

output "Exploration " & fldr.code
Dim obj ' Variablr qui référence l’objet courant

For Each obj In fldr.children
' Appel à la procédure afin de transférer le texte sur l’objet
DescriptionObjet obj
Next

Dim f ' Variable de référence au dossier
For Each f In fldr.Packages
'Appel à la procédure afin d’explorer les package enfants
ListeObjets f
Next

End Sub


'Procédure afin de déplacer le texte de la propriété Description vers Commentaire

Private Sub DescriptionObjet(CurrentObject)

if not CurrentObject.Iskindof(cls_NamedObject) then exit sub

output "Trouvé "+CurrentObject.ClassName+" """+CurrentObject.Name+""",   créé par " +CurrentObject.Creator+" le "+Cstr(CurrentObject.CreationDate)

' Si nous n'avons pas de texte au niveau du commentaire et que nous avons un texte au niveau de la description
If Len(Replace(CurrentObject.Comment," ",""))=0 and Len(Replace(CurrentObject.Description," ","")) > 0 Then
' Affichage des propriétés
Output "================================"
Output "================================"
set cls = CurrentObject
Output "Nom de l'objet : " + cls.Name
Output "Description (RTF): " + cls.Description
cls.Comment = Rtf2Ascii(cls.Description)
cls.Description = " "
Output ""
End If
End Sub

Laisser un commentaire

Contacter nous
300 characters left